identifiers; and some that do accept them will treat each word
as a different addressee (in this case, attempting to send a
copy of the message to "Al" and a copy to "Newman").
c. "George Lovell, Ted Hackle" <Shared-Mailbox at Office-1>
This form might be used to indicate that a single mailbox is
shared by several users. The quoted string is ignored by the
originating host's mailer, as "Shared-Mailbox at Office-1"
completely specifies the destination mailbox.
d. Wilt (the Stilt) Chamberlain at NBA
The "(the Stilt)" is a comment, which is NOT included in the
destination mailbox address handed to the originating system's
mailer. The address is the string "Wilt Chamberlain", with
exactly one space between the first and second words. (The
quotation marks are not included.)
II. Standard for the Format of Messages / 26
D. Examples
2. ADDRESS LISTS
Gourmets: Pompous Person <WhoZiWhatZit at Cordon-Bleu>,
Cooks: Childs at WGBH, Galloping Gourmet at
ANT (Australian National Television);
Wine Lovers: Drunk at Discount-Liquors,
Port at Portugal;;,
Jones at SEA
This group list example points out the use of comments, the
nesting of groups, and the mixing of addresses and groups.
Note that the two consecutive semi-colons preceding "Jones at
SEA" mean that Jones is NOT a member of the Gourmets group.
3. ORIGINATOR ITEMS
a. George Jones logs into his Host as "Jones". He sends mail
himself.
From: Jones at Host
or
From: George Jones <Jones at Host>
b. George Jones logs in as Jones on his Host. His secretary, who
logs in as Secy on her Host (SHost) sends mail for him.
Replies to the mail should go to George, of course.
From: George Jones <Jones at Host>
Sender: Secy at SHost
c. George Jones logs in as Group at Host. He sends mail himself;
replies should go to the Group mailbox.
From: George Jones <Group at Host>
d. George Jones' secretary sends mail for George in his capacity
as a member of Group while logged in as Secy at Host. Replies
should go to Group.
From: George Jones<Group at Host>
Sender: Secy at Host
Note that there need not be a space between "Jones" and the
"<", but adding a space enhances readability (as is the case
in other examples).
e. George Jones asks his secretary (Secy at Host) to send a
message for him in his capacity as Group. He wants his
secretary to handle all replies.
II. Standard for the Format of Messages / 27
D. Examples
From: George Jones <Group at Host>
Sender: Secy at Host
Reply-to: Secy at Host
f. A non-ARPANET user friend of George's, Sarah, is visting.
George's secretary sends some mail to a friend of Sarah in
computer-land. Replies should go to George, whose mailbox is
Jones at Host.
From: Sarah Friendly
Sender: Secy at Host
Reply-to: Jones at Host
g. George is a member of a committee. He wishes to have any
replies to his message go to all committee members.
From: George Jones
Sender: Jones at Host
Reply-To: Big-committee: Jones at Host,
Smith at Other-Host,
Doe at Somewhere-Else;
Note that if George had not included himself in the
enumeration of Big-committee, he would not have gotten a
reply; the presence of the "Reply-to:" field SUPERSEDES the
sending of a reply to the person named in the "From:" field.
h. (Example of INCORRECT USE)
George desires a reply to go to his secretary; therefore his
secretary leaves his mailbox address off the "From:" field,
leaving only his name, which is not, itself, a mailbox
address.
From: George Jones
Sender: Secy at SHost
THIS IS NOT PERMITTED. Replies are NEVER implicitly sent to
the "Sender:"; George's secretary should have used the
"Reply-to:" field, or the mail creating program she was using
should have forced her to.
i. George's secretary sends out a message which was authored
jointly by all the members of the "Big-committee".
From: Big-committee: Jones at Host,
Smith at Other-Host,
Doe at Somewhere-Else;
Sender: Secy at SHost
II. Standard for the Format of Messages / 28
D. Examples
4. COMPLETE HEADERS
a. Minimum required:
Date: 26 August 1976 1429-EDT
From: Jones at Host
b. Using some of the additional fields:
Date 26 August 1976 1430-EDT
From: George Jones<Group at Host>
Sender: Secy at SHOST
To: Al Newman at Mad-Host,
Sam Irving at Other-Host
Message-id: some string at SHOST
c. About as complex as you're going to get:
Date: 27 Aug 1976 0932-PDT
From: Ken Davis <KDavis at Other-Host>
Sender: KSecy at Other-Host
Reply-to: Sam Irving at Other-Host
Subject: Re: The Syntax in the RFC
To: George Jones <Group at Host>,
Al Newman at Mad-Host
cc: Tom Softwood <Balsa at Another-Host>,
Sam Irving at Other-Host,
Standard Distribution:
:File:
</main/davis/people/standard at Other Host,
"<Jones>standard.dist.3" at Tops-20-Host>
In-Reply-to: <some string at SHOST>
Message-ID: 4231.629.XYzi-What at Other-Host
Comment: Sam is away on business. He asked me to handle
his mail for him today. He'll be able to
provide a more accurate explanation tomorrow
when he returns.
III. References
III. REFERENCES
--- TELNET Protocol Specification. Network Information Center
No. 18639; Augmentation Research Center, Stanford Research
Institute: Menlo Park, August 1973.
Bhushan, A.K. The File Transfer Protocol. ARPANET Request for
Comments, No. 354, Network Information Center No. 10596;
Augmentation Research Center, Stanford Research Institute:
Menlo Park, July 1972.
Bhushan, A.K. Comments on the File Transfer Protocol. ARPANET
Request for Comments, No. 385, Network Information Center No.
11357; Augmentation Research Center, Stanford Research
Institute: Menlo Park, August 1972.
Bhushan, A.K., Pogran, K.T., Tomlinson, R.S., and White, J.E.
Standardizing Network Mail Headers. ARPANET Request for
Comments, No. 561, Network Information Center No. 18516;
Augmentation Research Center, Stanford Research Institute:
Menlo Park, September 1973.
Feinler, E.J. and Postel, J.B. ARPANET Protocol Handbook.
Network Information Center No. 7104; Augmentation Research
Center, Stanford Research Institute: Menlo Park, April 1976.
(NTIS AD A003890).
McKenzie, A. File Transfer Protocol. ARPANET Request for
Comments, No. 454, Network Information Center No. 14333;
Augmentation Research Center, Stanford Research Institute:
Menlo Park, February 1973.
Myer, T.H. and Henderson, D.A. Message Transmission Protocol.
ARPANET Request for Comments, No. 680, Network Information
Center No. 32116; Augmentation Research Center, Stanford
Research Institute: Menlo Park, 1975.
Neigus, N. File Transfer Protocol. ARPANET Request for
Comments, No. 542, Network Information Center No. 17759;
Augmentation Research Center, Stanford Research Institute:
Menlo Park, July 1973.
Postel, J.B. Revised FTP Reply Codes. ARPANET Request for
Comments, No. 640, Network Information Center No. 30843;
Augmentation Research Center, Stanford Research Institute:
Menlo Park, June 1974.
Appendix / 30
Alphabetical Listing of Syntax Rules
APPENDIX
A. ALPHABETICAL LISTING OF SYNTAX RULES
<2-digit-year> ::= <two decimal digits>
<4-digit-year> ::= <four decimal digits>
<24-hour-time> ::= <hour> <minute>
<addressee-field> ::= "To" ":" <address-list>
| "cc" ":" <address-list>
| "bcc" ":" <address-list>
| "Fcc" ":" <path-list>
<address-item> ::= <mach-addr-item>
| <group-name> ":" <address-list> ";"
| <any-name>
| <path>
<address-list> ::= <null> | <address-item>
| <address-item> "," <address-list>
<any-from-field> ::= "From" ":" <address-list>
<any-name> ::= <quoted-string>
<at-indicator> ::= "at" | "@"
<atom> ::= <a sequence of one or more TELNET ASCII
alpha-numeric or graphics characters,
excluding all control characters
(those characters with a decimal value
less than 33 or equal to 127) and
<delimeters> >
<comment> ::= "(" <TELNET ASCII characters, except
<crlf> > ")"
<cr> ::= <TELNET ASCII carriage return (decimal 13)>
<crlf> ::= <TELNET ASCII carriage return/line feed
(decimal 13, followed by decimal 10)>
<date> ::= <string-date> | <slash-date>
<date-field> ::= "Date" ":" <date-time>
<date-time> ::= <day> <date> <time>
<day> ::= <null> | <day-of-week> ","
<day-of-month> ::= <one or two decimal digits>
<day-of-week> ::= "Monday" | "Mon"
| "Tuesday" | "Tue"
| "Wednesday" | "Wed"
| "Thursday" | "Thu"
Appendix / 31
Alphabetical Listing of Syntax Rules
| "Friday" | "Fri"
| "Saturday" | "Sat"
| "Sunday" | "Sun"
<delimeter> ::= <specials> | <comment>
| <linear-white-space> | <crlf>
<field> ::= <field-name> ":" <field-body>
<field-body> ::= <field-body-contents>
| <field-body-contents> <crlf>
<linear-white-space-CHAR> <field-body>
<field-body-contents> ::= <the TELNET ASCII characters making up
the field body, as defined in the
following sections and consisting of
combinations of <atom>, <quoted-
string>, <text-line>, and <specials>
tokens>
<field-name> ::= <atom> | <atom> <field-name>
<group-name> ::= <phrase>
<headers> ::= <required-headers>
| <required-headers> <optional-headers>
<host-indicator> ::= <at-indicator> <host-name>
<host-name> ::= <atom> | <decimal host address>
<host-phrase> ::= <phrase> <host-indicator>
<hour> ::= <two decimal digits>
<lf> ::= <TELNET ASCII line feed (decimal 10)>
<linear-white-space>::= <linear-white-space-char>
| <linear-white-space-char>
<linear-white-space>
<linear-white-space-char>::= <space> | <horizontal-tab>
<mach-addr-item> ::= <mailbox> | <phrase> "<" <mailbox-list> ">"
<mach-addr-list> ::= <mach-addr-item>
| <mach-addr-item> "," <address-list>
<mach-from-field> ::= "From" ":" <mach-addr-item>
<mach-from-list> ::= "From" ":" <mach-addr-list>
<mach-host-phrase>::= "<" <host-phrase> ">"
<mailbox> ::= <host-phrase>
<mailbox-list> ::= <mailbox> | <mailbox> "," <mailbox-list>
<message> ::= <headers>
| <headers> <crlf> <message-text>
Appendix / 32
Alphabetical Listing of Syntax Rules
<message-text> ::= <a sequence of zero of more TELNET ASCII
characters>
<minute> ::= <two decimal digits>
<numeric-month> ::= <one or two decimal digits>
<optional-headers>::= <optional-header-field>
| <optional-headers> <optional-header-field>
<optional-header-field> ::= <addressee-field> | <extension-field>
<originator> ::= <mach-from-field>
| <mach-from-list> <sender-field>
| <mach-from-field> <reply-to-field>
| <any-from-field> <sender-field>
<reply-to-field>
<path> ::= ":" "File" ":" <path-name>
<path-item> ::= <host-phrase>
<path-list> ::= <path-item> | <path-item> "," <path-list>
<path-name> ::= <path-item> | "<" <path-list> ">"
<phrase> ::= <word> | <word> <phrase>
<phrase-list> ::= <null> | <phrase>
| <phrase> "," <phrase-list>
<reference-item> ::= <phrase> | <mach-host-phrase>
<reference-list> ::= <null> | <reference-item>
| <reference-item> "," <reference-list>
<quoted-string> ::= <double quote mark ("), decimal 34>
<a sequence of one or more TELNET
ASCII characters, where two adjacent
quotes are treated as a single quote
and part of the string> <">
<reply-to-field> ::= "Reply-To" ":" <mach-addr-list>
<required-headers> ::= <date-field> <originator>
<sender-field> ::= "Sender" ":" <host-phrase>
<slash-date> ::= <numeric-month> "/" <date-of-month>
"/" <2-digit-year>
<space> ::= <TELNET ASCII space (decimal 32)>
<specials> ::= "(" | ")" | "<" | ">"
| "@" | "," | ";" | ":" | <">
<string-date> ::= <day-of-month> <string-month>
<string-month> ::= "January" | "Jan" | "February" | "Feb"
Appendix / 33
Alphabetical Listing of Syntax Rules
| "March" | "Mar" | "April" | "Apr"
| "May" | "June" | "Jun"
| "July" | "Jul" | "August" | "Aug"
| "September"| "Sep" | "October" | "Oct"
| "November" | "Nov" | "December" | "Dec"
<tab> ::= <TELNET ASCII tab (decimal 9)>
<text-line> ::= <a sequence of one or more TELNET ASCII
characters excluding <cr> and <lf> >
<time> ::= <24-hour-time> "-" <time-zone>
<time-zone> ::= "GMT" | "Z" | "GDT" | "AST" | "ADT
| "EST" | "EDT" | "CST" | "CDT"
| "MST" | "MDT" | "PST" | "PDT"
| "YST" | "YDT" | "HST" | "HDT"
<user-defined-field> ::= <A <field> which has a <field-name> not
defined in this specification>
<word> ::= <atom> | <quoted-string>